-------------------------------------------------------------------------
-- Nicolas SOUQUET - 08/10/2008 - Découper une chaîne en ses caractères -
-------------------------------------------------------------------------
DECLARE @String VARCHAR(64)
SELECT @String = 'Ceci est un test ...';
 
WITH CTE_PARSE AS
(
    SELECT SUBSTRING(@String, 1, 1) Caractere, 1 Indice
  UNION ALL
    SELECT SUBSTRING(@String, Indice + 1, 1), Indice + 1
    FROM CTE_PARSE
    WHERE (Indice + 1) <= LEN(@String)
)
SELECT Caractere
FROM CTE_PARSE
OPTION (MAXRECURSION 0)
 
 
------------------------------------------------------------------------------------------------
-- Nicolas SOUQUET - 08/10/2008 - Découper les chaines d'une colonne d'une table en leurs mots -
------------------------------------------------------------------------------------------------
CREATE TABLE TbPhrase
(
  IDPhrase INT IDENTITY CONSTRAINT PK_TbPhrase PRIMARY KEY,
  Phrase VARCHAR(128)
)
GO
 
INSERT INTO dbo.TbPhrase VALUES ('C''est le printemps chic chic')
INSERT INTO dbo.TbPhrase VALUES ('Il fait beau demain')
GO
 
;WITH
  CTE (IDPhrase, Deb, Fin, Indice) AS  
  (  
      SELECT T.IDPhrase,
          1 Deb,
          CHARINDEX(CHAR(32), T.Phrase + CHAR(32)) Fin,
          1 AS Indice
      FROM dbo.TbPhrase AS T
    UNION ALL  
      SELECT T.IDPhrase,
          CTE.Fin + 1,
          CHARINDEX(CHAR(32), T.Phrase + CHAR(32), CTE.Fin + 1),
          CTE.Indice + 1
      FROM CTE
      JOIN dbo.TbPhrase AS T ON T.IDPhrase = CTE.IDPhrase
      WHERE CHARINDEX(CHAR(32), T.Phrase + CHAR(32), CTE.Fin + 1) > 0
  )
SELECT T.Phrase,
    SUBSTRING(T.Phrase, CTE.Deb , CTE.Fin - CTE.Deb) AS Mots
FROM CTE  
JOIN dbo.TbPhrase AS T ON T.IDPhrase = CTE.IDPhrase
ORDER BY CTE.IDPhrase
 
--------------------------------------------------------------------------------------------
-- Nicolas SOUQUET - 08/10/2008 - Decouper une chaine en ses mots séparés par des virgules -
--------------------------------------------------------------------------------------------
DECLARE @str VARCHAR(64)
SET @str = 'toto,titi,tutu,tata';
 
WITH CTE (Deb, Fin) AS
(
  SELECT 1 Deb, CHARINDEX(',', @str + ',') Fin
 UNION ALL
  SELECT Fin + 1, CHARINDEX(',', @str + ',', Fin + 1)
  FROM CTE
  WHERE CHARINDEX( ',', @str + ',', Fin + 1 ) > 0
)
SELECT SUBSTRING(@str, Deb , Fin - Deb), Deb, Fin
FROM CTE
 
--------------------------------------------------------------------------
-- Nicolas SOUQUET - 08/10/2008 - Découper une chaîne avec un séparateur -
--------------------------------------------------------------------------
DECLARE @String VARCHAR(64) SET @String = 'un,deux,trois,quatre,cinq';
DECLARE @Separator CHAR(1) SET @Separator = ',';
WITH INDICES AS
(
    SELECT 0 Deb, 1 Fin
  UNION ALL
    SELECT Fin, CHARINDEX(@Separator, @String, Fin) + LEN(@Separator)
    FROM INDICES
    WHERE Fin > Deb
)
SELECT SUBSTRING(
          @String,
          Deb,
          CASE
            WHEN Fin > LEN(@Separator) THEN Fin - Deb - LEN(@Separator)
            ELSE LEN(@String) - Deb + 1
          END
        ) String,
        Deb,
        Fin,
        LEN(@String) - Deb + 1 Lgr
FROM INDICES WHERE Deb > 0
 
---------------------------------------------------------------------------------------------------------------------
-- Nicolas SOUQUET - 08/10/2008 - Fonction de mise en majuscule de la première lettre de tous les mots d'une phrase -
---------------------------------------------------------------------------------------------------------------------
CREATE FUNCTION fPremiereLettreMajuscule (@str VARCHAR(8000))
  RETURNS VARCHAR(8000)
AS
BEGIN
  DECLARE @result VARCHAR(8000);
 
  -- Extraction des mots de la phrase par recherche des espaces
  WITH
    CTE_Espaces AS
    (
        SELECT 1 Deb, CHARINDEX(' ', @str + ' ') Fin
      UNION ALL
        SELECT Fin + 1, CHARINDEX(' ', @str + ' ', Fin + 1)
        FROM CTE_Espaces
        WHERE CHARINDEX(' ', @str + ' ', Fin + 1 ) > 0
    )
  -- Formatage des mots et concaténation
  SELECT @result = ISNULL(@result, '') + UPPER(SUBSTRING(SUBSTRING(@str, Deb, Fin), 1, 1)) + LOWER(SUBSTRING(SUBSTRING(@str, Deb, Fin - Deb + 1), 2, Fin))
  FROM CTE_Espaces
 
  RETURN @result
END
GO
 
-----------------------------------------------------------------------------
-- Nicolas SOUQUET - 08/10/2008 - Créer une plage de dates entre deux dates -
-----------------------------------------------------------------------------
DECLARE @DateDeb DATETIME SET @DateDeb = '20080810'
DECLARE @DateFin DATETIME SET @DateFin = '20080820';
WITH DATES AS
(
    SELECT @DateDeb Date, 1 Indice
  UNION ALL
    SELECT @DateDeb + Indice Date, Indice + 1 Indice
    FROM DATES
    WHERE Date < @DateFin
)
SELECT * FROM DATES
 
-------------------------------------------------------------------------
-- Nicolas SOUQUET - 08/10/2008 - Faire la somme de nombres d'une plage -
-------------------------------------------------------------------------
DECLARE @nMinBound INT,
    @nMaxBound INT
 
SET @nMinBound = 1
SET @nMaxBound = 10000;
 
WITH SommeDeNombres AS
(
    SELECT 0 Somme, @nMinBound minBound, @nMaxBound maxBound
  UNION ALL
    SELECT Somme + minBound, minBound + 1, maxBound
    FROM SommeDeNombres
    WHERE minBound <= maxBound
)
SELECT Somme
FROM SommeDeNombres
WHERE minBound = maxBound + 1
OPTION (MAXRECURSION 0)
 
----------------------------------------------------------------------------------------------------
-- Nicolas SOUQUET - 08/10/2008 - Générer la liste de tous les jours d'un mois de l'année courante -
----------------------------------------------------------------------------------------------------
DECLARE @month TINYINT
SET @month = 11;
 
WITH
  CTE_Days AS
  (
      SELECT DATEADD(month, @month, DATEADD(month, -MONTH(GETDATE()), DATEADD(day, -DAY(GETDATE()) + 1, CAST(FLOOR(CAST(GETDATE() AS FLOAT)) AS DATETIME)))) D
    UNION ALL
      SELECT DATEADD(day, 1, D)
      FROM CTE_Days
      WHERE D < DATEADD(day, -1, DATEADD(month, 1, DATEADD(month, @month, DATEADD(month, -MONTH(GETDATE()), DATEADD(day, -DAY(GETDATE()) + 1, CAST(FLOOR(CAST(GETDATE() AS FLOAT)) AS DATETIME))))))
  )
SELECT D
FROM CTE_Days