Voici un script SQL de M. Ouriel OHANA permettant de générer les comptes de connexion afin de migrer des bases d’une instance de niveau 2005 à 2008.
Pour une migration de 7 ou 2000 à 2005/8 voir : http://support.microsoft.com/kb/246133

USE [master] 

GO 

IF OBJECT_ID ('sp_help_revlogin2') IS NOT NULL 

  DROP PROCEDURE sp_help_revlogin2 

GO 

 

/****** Object:  StoredProcedure [dbo].[sp_help_revlogin2]    Script Date: 09/03/2008 16:59:01 ******/ 

SET ANSI_NULLS ON 

GO 

SET QUOTED_IDENTIFIER ON 

GO 

CREATE PROCEDURE [dbo].[sp_help_revlogin2] @login_name sysname = NULL, @destination varchar(12)=NULL, @job_id uniqueidentifier=null, @step_id int=null 

WITH ENCRYPTION 

AS 

DECLARE @name sysname 

DECLARE @type varchar (1) 

DECLARE @hasaccess int 

DECLARE @denylogin int 

DECLARE @is_disabled int 

DECLARE @PWD_varbinary  varbinary (256) 

DECLARE @PWD_string  varchar (514) 

DECLARE @SID_varbinary varbinary (85) 

DECLARE @SID_string varchar (514) 

DECLARE @tmpstr  varchar (1024) 

DECLARE @is_policy_checked varchar (3) 

DECLARE @is_expiration_checked varchar (3) 

DECLARE @nom_srv sysname 

DECLARE @nom_inst sysname 

 

DECLARE @defaultdb sysname 

 

if charindex('\',@@servername)>0 

begin 

  select @nom_srv=left(@@servername,charindex('\',@@servername)-1) 

  select @nom_inst=right(@@servername,len(@@servername)-charindex('\',@@servername)) 

end 

else 

begin 

  select @nom_srv=@@servername 

  select @nom_inst=@@servername 

end 

 

--le parametre @destination est passe avec la valeur NULL ou 'table' 

--NULL    => on souhaite afficher les ordres create login a l'ecran 

--'table'  => on souhaite stocker les ordres create login dans la table admin..ta_logins de l instance d admin. 

--Le job AD_logins appelle cette proc avec la valeur 'table' pour ce parametre car on stocke quotidiennement les ordres create login 

--dans la base d'admin afin de s'en servir en cas de reconstruction d'une instance 

 

 

IF (@login_name IS NULL) 

  DECLARE login_curs CURSOR FOR 

 

      SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin FROM  

sys.server_principals p LEFT JOIN sys.syslogins l 

      ON ( l.name = p.name ) WHERE p.type in ('S','U','G') AND p.name <> 'sa' 

ELSE 

  DECLARE login_curs CURSOR FOR 

 

 

      SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin FROM  

sys.server_principals p LEFT JOIN sys.syslogins l 

      ON ( l.name = p.name ) WHERE p.type ='S' AND p.name = @login_name 

OPEN login_curs 

 

FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin 

IF (@@fetch_status = -1) 

BEGIN 

  PRINT 'No login(s) found.' 

  CLOSE login_curs 

  DEALLOCATE login_curs 

  RETURN -1 

END 

SET @tmpstr = '/* sp_help_revlogin script ' 

--PRINT @tmpstr 

SET @tmpstr = '** Generated ' + CONVERT (varchar, GETDATE()) + ' on ' + @@SERVERNAME + ' */' 

--PRINT @tmpstr 

PRINT '' 

WHILE (@@fetch_status <> -1) 

BEGIN 

  IF (@@fetch_status <> -2) 

  BEGIN 

    PRINT '' 

    SET @tmpstr = '-- Login: ' + @name 

    --PRINT @tmpstr 

    IF (@type IN ( 'G', 'U')) 

    BEGIN -- NT authenticated account/group 

 

      SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' FROM WINDOWS WITH DEFAULT_DATABASE = [' + @defaultdb + ']' 

    END 

    ELSE BEGIN -- SQL Server authentication 

        -- obtain password and sid 

            SET @PWD_varbinary = CAST( LOGINPROPERTY( @name, 'PasswordHash' ) AS varbinary (256) ) 

        EXEC sp_hexadecimal @PWD_varbinary, @PWD_string OUT 

        EXEC sp_hexadecimal @SID_varbinary,@SID_string OUT 

 

        -- obtain password policy state 

        SELECT @is_policy_checked = CASE is_policy_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name 

        SELECT @is_expiration_checked = CASE is_expiration_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name 

 

            SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' WITH PASSWORD = ' + @PWD_string + ' HASHED, SID = ' + @SID_string + ', DEFAULT_DATABASE = [' + @defaultdb + ']' 

 

        IF ( @is_policy_checked IS NOT NULL ) 

        BEGIN 

          SET @tmpstr = @tmpstr + ', CHECK_POLICY = ' + @is_policy_checked 

        END 

        IF ( @is_expiration_checked IS NOT NULL ) 

        BEGIN 

          SET @tmpstr = @tmpstr + ', CHECK_EXPIRATION = ' + @is_expiration_checked 

        END 

    END 

    IF (@denylogin = 1) 

    BEGIN -- login is denied access 

      SET @tmpstr = @tmpstr + '; DENY CONNECT SQL TO ' + QUOTENAME( @name ) 

    END 

    ELSE IF (@hasaccess = 0) 

    BEGIN -- login exists but does not have access 

      SET @tmpstr = @tmpstr + '; REVOKE CONNECT SQL TO ' + QUOTENAME( @name ) 

    END 

    IF (@is_disabled = 1) 

    BEGIN -- login is disabled 

      SET @tmpstr = @tmpstr + '; ALTER LOGIN ' + QUOTENAME( @name ) + ' DISABLE' 

    END 

    PRINT @tmpstr 

  END 

   FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin 

   END 

CLOSE login_curs 

DEALLOCATE login_curs 

RETURN 0 

go

Pour la procédure sp_hexadecimal voir la papier de Microsoft cité en référence.

Merci à M. OHANA !

-------- 

Frédéric Brouard, SQLpro - ARCHITECTE DE DONNÉES, http://sqlpro.developpez.com/ 

Expert bases de données relationnelles et langage SQL. MVP Microsoft SQL Server 

www.sqlspot.com : modélisation, conseil, audit, optimisation, tuning, formation 

* * * * *  Enseignant CNAM PACA - ISEN Toulon - CESI Aix en Provence  * * * * *